Shopping Hospedagem Fórum Contato
     
   O portal do desenvolvedor ASP Florianópolis-SC, Domingo - 23 de Setembro de 2018  
Busca

Menu do site
Efetuar Login
Usuário:

Senha:

 Esqueceu a senha?
Login automático

 Cadastre-se
Processar transações de dados de uma página ASP
Avaliações: 5   -   Minha nota: Média Geral: 21  

Este procedimento passo a passo demonstra como processar transações de dados de uma página ASP se as transações usarem o ActiveX Data Objects (ADO) para conexão com um banco de dados.

1. Pré-requisitos
Esta lista apresenta o hardware, software, a infra-estrutura de rede e os pacotes de serviços recomendados necessários:


Microsoft Active Server Pages
Microsoft Internet Information Server
Este artigo supõe que você esteja familiarizado com os seguintes tópicos:


Terminologia e sintaxe do ASP
Tecnologias de acesso a dados (Microsoft ActiveX Data Objects)

2. Processando transações de dados no ASP
No Bloco de notas, crie uma nova página ASP chamada DataTran.asp e cole o seguinte código:


<%@ TRANSaction=Required%>
<%
Option Explicit
On Error Resume Next
Dim oConn, oRS

Set oConn = Server.CreateObject("ADODB.Connection")
oConn.Open "Provider=SQLOleDB;server=servername;Initial Catalog=pubs;uid=sa;pwd="
if err.Number <> 0 Then
Response.Write "<BR>Erro ao abrir conexão...<BR>"
Response.Write "<BR>Descrição do erro: " & err.Description & "...<BR>"
ObjectContext.SetAbort
Response.End
else
Response.Write "A conexão foi aberta com êxito...<BR>"
ObjectContext.SetComplete
End If


oConn.Execute "Select * from Authors"
if err.Number <> 0 Then
Response.Write "<BR>Erro ao executar a consulta...<BR>"
Response.Write "<BR>Descrição do erro: " & err.Description & "...<BR>"
oConn.Close
Set oConn = Nothing
ObjectContext.SetAbort
Response.End
else
Response.Write "<BR>A consulta foi concluída com êxito...<BR>"
ObjectContext.SetComplete
End If

oConn.Close
Response.Write "<BR>A conexão foi fechada com êxito...<BR>"
set oConn = Nothing
Response.Write "<BR>O teste foi concluído com êxito...<BR>"

Sub OnTransactionCommit()
Response.Write "<p><B>A transação foi realizada</B>."
Response.Write "Esta mensagem é proveniente de "
Response.Write "Manipulador de eventos OnTransactionCommit()."
End Sub

Sub OnTransactionAbort()
Response.Write "<p><B>A transação foi anulada</B>."
Response.Write "Esta mensagem é proveniente de "
Response.Write "Manipulador de eventos OnTransactionAbort()."
End Sub

%>

O exemplo de código acima tenta conectar-se ao banco de dados PUBS padrão do Microsoft SQL Server. Se você não tiver o SQL Server instalado, deverá alterar a seqüência de conexão e a instrução SQL.

Além disso, não se esqueça de alterar a seqüência de conexão na linha a seguir do código para incluir o nome do servidor, a identificação do usuário (UID) e a senha (PWD) corretos:


oConn.Open "Provider=SQLOleDB;server=servername;Initial Catalog=pubs;uid=sa;pwd="

No menu Arquivo, clique em Salvar. Na caixa de listagem suspensa Salvar em, clique na pasta C:\Inetpub\Wwwroot. Na caixa de listagem suspensa Salvar como tipo, clique em Todos os arquivos. Na caixa de listagem Nome do arquivo, digite DataTran.asp.


No navegador da Web, execute a página ASP (por exemplo, http://localhost/DataTran.asp).


Se a seqüência de conexão do OLE DB e a consulta forem válidas, será retornada a seguinte saída:


A conexão foi aberta com êxito...

A consulta foi concluída com êxito...

A conexão foi fechada com êxito...

O teste foi concluído com êxito...

A transação foi realizada. Esta mensagem é proveniente de
Manipulador de eventos OnTransactionCommit().
Se a seqüência de conexão OLE DB for inválida ou se sua consulta for incorreta, você receberá uma mensagem de erro e o evento OnTransactionAbort será acionado. São retornadas as seguintes saídas:


A conexão foi aberta com êxito...

Erro ao executar a consulta...

Descrição do erro: Nome inválido do objeto 'Author'....

A transação foi anulada. Esta mensagem é proveniente de Manipulador de eventos OnTransactionAbort().






SuperASP do Brasil Ltda

03.066.522/0001-84
Av. Rio Branco 433 - Centro - Florianopolis - SC
Contato

© 2001/2008 - Superasp do Brasil Ltda. Todos os direitos reservados